1. Выбор одного значения из списка в режиме использования модальности

Необходимо включить режим использования модальности, если он отключен;

Воспользуемся методом ВыбратьИзСписка ()

&НаКлиенте
Процедура ВыбратьЗнакЗодиака(Команда)
	ЗнакиЗодиака = Новый СписокЗначений; 

	ЗнакиЗодиака.Добавить("Весы"); 
	ЗнакиЗодиака.Добавить("Телец"); 
	ЗнакиЗодиака.Добавить("Скорпион"); 

	ВыбранноеЗначение = ВыбратьИзСписка(ЗнакиЗодиака); 

	Если ВыбранноеЗначение <> Неопределено Тогда 
		Сообщить(ВыбранноеЗначение.Значение); 
	КонецЕсли;
КонецПроцедуры

Метод ВыбратьИзМеню () работает по аналогии с методом ВыбратьИзСписка ();

2. Выбор одного значения из списка без использования модальности

Метод: ПоказатьВыборЭлемента ()

&НаКлиенте
Процедура ВыбратьЗнакЗодиака(Команда)
	ЗнакиЗодиака = Новый СписокЗначений;
	ЗнакиЗодиака.Добавить("Весы");
	ЗнакиЗодиака.Добавить("Телец");
	ЗнакиЗодиака.Добавить("Скорпион");

	ОповещениеПослеВыбораЭлемента = Новый ОписаниеОповещения(
	    "СообщитьРезультат", ЭтотОбъект);

	ЗнакиЗодиака.ПоказатьВыборЭлемента(
	    ОповещениеПослеВыбораЭлемента,
	    "Выберите Ваш знак зодиака");
КонецПроцедуры

&НаКлиенте
Процедура СообщитьРезультат(Элемент, Параметры) Экспорт
	Если Элемент <> Неопределено Тогда
		Сообщить(Элемент.Значение);
	КонецЕсли;
КонецПроцедуры

3. Выбор нескольких значений из списка в режиме использования модальности

Метод: ОтметитьЭлементы

&НаКлиенте
Процедура ВыбратьЗнакЗодиака(Команда)
	ЗнакиЗодиака = Новый СписокЗначений; 

	ЗнакиЗодиака.Добавить("Весы"); 
	ЗнакиЗодиака.Добавить("Телец"); 
	ЗнакиЗодиака.Добавить("Скорпион"); 

	ВыбранноеЗначение = ЗнакиЗодиака.ОтметитьЭлементы("Выберите знаки зодиака");

	Для каждого ЗнакЗодиака Из ЗнакиЗодиака Цикл
		Если ЗнакЗодиака.Пометка Тогда
			Сообщить(ЗнакЗодиака);
		КонецЕсли;
	КонецЦикла; 
КонецПроцедуры

4. Выбор нескольких значений из списка без использования модальности

Метод: ПоказатьОтметкуЭлементов ()

&НаКлиенте
Процедура ВыбратьЗнакЗодиака(Команда)
	ЗнакиЗодиака = Новый СписокЗначений; 
	
	ЗнакиЗодиака.Добавить("Весы"); 
	ЗнакиЗодиака.Добавить("Телец"); 
	ЗнакиЗодиака.Добавить("Скорпион");
	
	ОповещениеПослеВыбора = Новый ОписаниеОповещения(
	"СообщитьРезультат", ЭтотОбъект);
	
	ЗнакиЗодиака.ПоказатьОтметкуЭлементов(
	ОповещениеПослеВыбора, "Выберите знаки зодиака");
КонецПроцедуры

&НаКлиенте
Процедура СообщитьРезультат(Элементы, Параметры) Экспорт
	Если Элементы <> Неопределено Тогда
		Для Каждого ЗнакЗодиака Из Элементы Цикл
			Если ЗнакЗодиака.Пометка Тогда
				Сообщить(ЗнакЗодиака.Значение);
			КонецЕсли;
		КонецЦикла;
	КонецЕсли;
КонецПроцедуры